Colle d'informatique XII

> restart;

XI.1

> P:=X^4+a*X^3+sqrt(3)*X^2+X+b;

> image:=subs(X=2+2*I,P);

> assume(a,real);assume(b,real);

> solve(image);

Ça ne marche pas.

> eqs:={Re(image),Im(image)};incs:={a,b};

> solve(eqs,incs);

> assign(%);

Ceci permet l'affectation des valeurs obtenues aux inconnues a et b

> 'a'=a;'b'=b;

> P;

> solve(P);

> evalf(-911+8*sqrt(3));

Ainsi il n'y a pas de racine réelle.

> factor(P);

Ceci est la décomposition de Gauss de P

> factor(P,{I,sqrt(-911+8*sqrt(3))});

Et cela la décomposition de d'Alembert.

> restart;

XI.2

Pour avoir un o(x^7), il faut demander un O(x^8).

> series(tan(x),x,8);

On fait un premier essai, en demandant un O(x^9)

> series((1-cos(x))/x^2,x,9);

On n'obtient qu'un O(x^7). En fait, Maple a fait ses calculs avec un O(x^9) puis a divisé par x^2. Il faut anticiper ceci par une étude a priori de l'ordre du développement. Ainsi

> series((1-cos(x))/x^2,x,11);

Ici encore, c'est une exponentielle d'une expression comportant un x au dénominateur. Il va y avoir une simplification par x. On demande donc un O(x^4) pour avoir un O(x^3).

> series((1-x+x^2)^(1/x),x,4);

> restart;

XI.3

> f:=sin(x)-(a*x+b*x^3+c*x^5)/(1+d*x^2+e*x^4);

Je sais a priori que le DL de sin(x) commence par x, celui de la fraction par ax. Si je veux que f ne soit pas de l'ordre de x, il faut que a=1.

f est impaire, donc tous les coefficients pairs dans sont DL seront nuls. J'ai besoin d'égaler au moins 5 coefficients non nuls à zéro pour pouvoir déterminer mes cinq inconnues, c'est-à-dire que je dois avoir les termes en x, x^3, x^5, x^7, x^9. Je demande donc un DL (faible) à l'ordre 10.

> DL:=series(f,x,10);

> P:=convert(DL,polynom);

> syst:={coeffs(P,x)};

> inc:={a,b,c,d,e};

> solve(syst,inc);

> assign(%);

> series(f,x,12);

> convert(%,polynom);

Ceci est un équivalent de f.

> restart;

XI.4

> P:=X^6+sqrt(2)*X^5+a*X^2+b*X+c;

> Pderiv0:=P;

> for i from 1 to 3 do Pderiv||i:=diff(P,X$i) od;

On traduit la condition par l'existence d'une racine commune à ces 4 polynômes, c'est-à-dire que le système formé par 4 équations (nullité de ces 4 polynômes) à 4 inconnues (a,b,c,X) admet au moins une solution.

> syst:={seq(Pderiv||i,i=0..3)};

> inc:={a,b,c,X};

> solve(syst,inc);

Ainsi, il faut et il suffit de prendre a=b=c=0 ou a=5/4, b=3sqrt(2)/4 et c=1/4. Dans ce dernier cas, -sqrt(2)/2 est racine au moins quadruple.

> restart;

XI.5

On cherche P sous la forme

> P:=a*X^3+b*X^2+c*X+d;

On traduit les différentes conditions~:

> cond1:=subs(X=1,P)-7; # traduit que P(1)=7

> cond2:=subs(X=8,P)+2; # traduit que P(8)=-2

> Pprime:=diff(P,X);

> cond3:=subs(X=1,Pprime); # C'est bien une cond nécessaire. Traduit qu'en 1, P admet un point critique.

> cond4:=subs(X=8,Pprime); # idem

> syst:={seq(cond||i,i=1..4)};

> inc:={a,b,c,d};

> solve(syst,inc);

> assign(%);

> P;

> plot(P,X=-4..10);

On a raisonné par condition nécessaire. Si un polynôme P convient, c'est nécessairement celui-ci. Réciproquement, on "voit" graphiquement qu'il convient. On pourrait faire une étude plus précise des variations pour montrer que P admet effectivement deux extrema en 1 et 8.

> restart;

XI.6

> f:=x->a/sin(x)+b/tan(x)+c*x/cos(x)+d/x;

On fait un DL de f avec suffisament de termes non nuls pour obtenir un système de 3 équations. En effet, si on obtient 4 équations, on aura (sans doute) un unique quadruplet solution. Or (0,0,0,0) conviendra, et ce cas est exclu.

> dev:=series(f(x),x,6);

> P:=convert(dev,polynom);

> syst:={coeffs(P,x)};

> inc:={a,b,c,d};

> solve(syst,inc);

> assign(%);

> f(x);

Il apparaît clairement que toute fonction solution s'écrit c*f_1, où f_1 est~:

> f_1:=unapply(subs(c=1,f(x)),x);

C'est-à-dire que l'ensemble des solutions est la droite vectorielle engendrée par f_1.

Remarque~: selon les cas, la constante c peut être remplacée par d, a ou b... cela dépend de l'humeur de Maple :-)

> restart;

XI.7

> P:=X^3+a*X^2+a*X+1;

> solve(P,X);

On remarque que -1 est toujours racine de P. Cherchons le quotient dans la division de P par X+1

> Q:=quo(P,X+1,X);

1er cas : -1 est l'une des deux racines dont la somme fait 1. L'autre est alors 2, et est racine de Q donc

> subs(X=2,Q)=0;

> a=solve(%,a);

2ème cas : les racines dont la somme fait 2 sont les racines de Q, dont la somme fait 1-a (rel coefficients racines) d'où

> a=0;

Dans ce deuxième cas, les racines en question sont -j et -j^2.

> restart;

XI.8

> P:=4*X^4-16*X^3+2*X^2+28*X-49;

> racines:=[solve(P,X)];

Attention, il y a bien deux racines complexes parmi les racines~: deux des radicaux sont les radicaux de nombres négatifs.

> factor(P,sqrt(11+7*sqrt(5)));

> somme:=sum(racines[i]^3,i=1..4);

> simplify(somme);

Expliquer pourquoi c'est un entier... C'est une question un peu "bizarre". Est-ce que l'examinateur attendait simplement une réponse du genre "parce que cette somme peu s'exprimer avec les fonctions symétriques élémentaires, donc en fonction des coefficients du polynôme, donc sera un entier", ou attendait-il un raisonnement plus détaillé~? Détaillons~:

> a:=[a1,a2,a3,a4];

> s1:=sum(a[i],i=1..4);

> s2:=sum(sum(a[i]*a[j],j=i+1..4),i=1..4);

> s3:=sum(sum(sum(a[i]*a[j]*a[k],k=j+1..4),j=i+1..4),i=1..4);

> s4:=product(a[i],i=1..4);

> s1^3-sum(a[i]^3,i=1..4);

> simplify(%);

> %-6*s3;

> %+9*s3;

> %-3*s1*s2;

> simplify(%);

On vient de montrer la formule :

> 'sum(a[i]^3,i=1..4)'=('s1'^3-6*'s3')+9*'s3'-3*'s1'*'s2';

vérifions~:

> rhs(%)-lhs(%);

> simplify(%);

Pour le polynôme qui nous concerne, s1=4, s2=1/2, s3=-7 et s4=-49/4, Comme la somme ne fait intervenir que s1 et s3, qui sont entier, le résultat sera entier.

> subs({sigma1=4,sigma2=1/2,sigma3=-7},sigma1^3+3*sigma3-3*sigma1*sigma2);